users/tdback/desktop.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

{ config, pkgs, ... }:
let
  mkDirs = defined:
    let
      home = config.home.homeDirectory;
      dirs = [ "desktop" "documents" "download" "music" "pictures" "publicShare" "templates" "videos" ];
    in
      builtins.listToAttrs (
        builtins.map (dir: {
          name = dir;
          value =
            if builtins.hasAttr dir defined then
              "${home}/${defined.${dir}}"
            else
              null;
        }) dirs
      );
in
{
  imports = [
    ./modules/alacritty
    ./modules/dunst
    ./modules/email
    ./modules/firefox
    ./modules/irc
    ./modules/mpd
    ./modules/ncmpcpp
    ./modules/neomutt
    ./modules/polybar
    ./modules/rofi
    ./modules/tmux
    ./modules/x11
  ];

  home.packages = with pkgs.unstable; [
    clang
    feh
    (ffmpeg.override { withXcb = true; })
    flameshot
    gimp
    gitu
    mpc-cli
    mpv
    pavucontrol
    pamixer
    pciutils
    signal-desktop
    sxiv
    tidal-dl
    xclip
    yt-dlp
    zathura
  ];

  xdg = {
    enable = true;
    userDirs = {
      enable = true;
      createDirectories = true;
    } // (mkDirs { documents = "documents"; download = "downloads"; });
  };

  qt = {
    enable = true;
    platformTheme.name = "gtk3";
    style = {
      name = "adwaita-dark";
      package = pkgs.adwaita-qt;
    };
  };

  gtk = {
    enable = true;
    gtk3.extraConfig.gtk-application-prefer-dark-theme = 1;
    gtk4.extraConfig.gtk-application-prefer-dark-theme = 1;
  };
}